QT       += core gui multimedia testlib

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++11
CONFIG+=sdk_no_version_check
# You can make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

SOURCES += \
    about.cpp \
    analyzer.cpp \
    camp.cpp \
    campmode.cpp \
    cdac.cpp \
    csong.cpp \
    cspeaker.cpp \
    delegatepathitem.cpp \
    library.cpp \
    main.cpp \
    mainwindow.cpp

HEADERS += \
    about.h \
    analyzer.h \
    camp.h \
    campmode.h \
    cdac.h \
    csong.h \
    cspeaker.h \
    delegatepathitem.h \
    library.h \
    mainwindow.h

FORMS += \
    about.ui \
    analyzer.ui \
    library.ui \
    mainwindow.ui

TARGET = "PA Calculator"


macx {
    ICON = PA_Calculator.icns
}

win32 {
    RC_ICONS = PA_Calculator.ico
}
# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target

RESOURCES += \
    resources.qrc

VERSION=1.1.0
QMAKE_TARGET_PRODUCT = "PA-Calculator"
QMAKE_TARGET_COMPANY = "Alexander Diamadis"
QMAKE_TARGET_COPYRIGHT = "Copyright (c) 2022 by Alexander Diamadis"

win32 {
    commit = $$system("FOR /F \"tokens=*\" %H IN ('git rev-parse --short HEAD') DO @SET /A DECIMAL=0x%H")
} else {
    commit = $$system("printf '%d' 0x`git rev-parse --short HEAD`")
}


DEFINES += APP_VERSION=\"\\\"$${VERSION}\\\"\" \
           APP_PRODUCT=\"\\\"$${QMAKE_TARGET_PRODUCT}\\\"\" \
           APP_COMPANY=\"\\\"$${QMAKE_TARGET_COMPANY}\\\"\" \
           APP_COMMIT=\"\\\"$${commit}\\\"\" \
           APP_COPYRIGHT=\"\\\"$${QMAKE_TARGET_COPYRIGHT}\\\"\"

# Library Libnyquist

macx: LIBS += -L$$PWD/../libs/libnyquist/lib-macx/ -llibnyquist

INCLUDEPATH += $$PWD/../libs/libnyquist/include
DEPENDPATH += $$PWD/../libs/libnyquist/include

macx: PRE_TARGETDEPS += $$PWD/../libs/libnyquist/lib-macx/liblibnyquist.a


macx: LIBS += -L$$PWD/../libs/libnyquist/lib-macx/ -llibwavpack

INCLUDEPATH += $$PWD/../libs/libnyquist/include
DEPENDPATH += $$PWD/../libs/libnyquist/include

macx: PRE_TARGETDEPS += $$PWD/../libs/libnyquist/lib-macx/liblibwavpack.a

# Library getLoudness


macx: LIBS += -L$$PWD/../libs/getLoudness/macx/ -lgetLoudness

macx: INCLUDEPATH += $$PWD/../libs/getLoudness/macx
macx: DEPENDPATH += $$PWD/../libs/getLoudness/macx

macx: PRE_TARGETDEPS += $$PWD/../libs/getLoudness/macx/libgetLoudness.a