QT       += core gui multimedia network concurrent

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++11
CONFIG+=sdk_no_version_check
CONFIG += warn_off

SOURCES += \
    about.cpp \
    analyzer.cpp \
    camp.cpp \
    campmode.cpp \
    cdac.cpp \
    csong.cpp \
    cspeaker.cpp \
    delegatepathitem.cpp \
    library.cpp \
    main.cpp \
    mainwindow.cpp

HEADERS += \
    about.h \
    analyzer.h \
    camp.h \
    campmode.h \
    cdac.h \
    csong.h \
    cspeaker.h \
    delegatepathitem.h \
    library.h \
    mainwindow.h

FORMS += \
    about.ui \
    analyzer.ui \
    library.ui \
    mainwindow.ui

TARGET = "PA Calculator"


macx {
    ICON = PA_Calculator.icns
}

win32 {
    RC_ICONS = PA_Calculator.ico
}
# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target

RESOURCES += \
    resources.qrc

VERSION=1.4.0
QMAKE_TARGET_PRODUCT = "PA-Calculator"
QMAKE_TARGET_COMPANY = "DKM-Tech"
QMAKE_TARGET_COPYRIGHT = "Copyright (c) 2023 by Alexander Diamadis"

commit = $$system(git rev-parse --short=8 HEAD)


DEFINES += APP_VERSION=\"\\\"$${VERSION}\\\"\" \
           APP_PRODUCT=\"\\\"$${QMAKE_TARGET_PRODUCT}\\\"\" \
           APP_COMPANY=\"\\\"$${QMAKE_TARGET_COMPANY}\\\"\" \
           APP_COMMIT=\"\\\"$${commit}\\\"\" \
           APP_COPYRIGHT=\"\\\"$${QMAKE_TARGET_COPYRIGHT}\\\"\"

# Library Libnyquist
INCLUDEPATH += $$PWD/../libs/libnyquist/include
DEPENDPATH += $$PWD/../libs/libnyquist/include

macx: LIBS += -L$$PWD/../libs/libnyquist/lib-macx/ -llibnyquist
macx: PRE_TARGETDEPS += $$PWD/../libs/libnyquist/lib-macx/liblibnyquist.a

win32:CONFIG(release, debug|release): LIBS += -L$$PWD/../libs/libnyquist/lib-win32/ -llibnyquist
else:win32:CONFIG(debug, debug|release): LIBS += -L$$PWD/../libs/libnyquist/lib-win32/ -llibnyquist_d


macx: LIBS += -L$$PWD/../libs/libnyquist/lib-macx/ -llibwavpack
macx: PRE_TARGETDEPS += $$PWD/../libs/libnyquist/lib-macx/liblibwavpack.a

win32:CONFIG(release, debug|release): LIBS += -L$$PWD/../libs/libnyquist/lib-win32/ -llibwavpack
else:win32:CONFIG(debug, debug|release): LIBS += -L$$PWD/../libs/libnyquist/lib-win32/ -llibwavpack_d

# Library getLoudness

macx: INCLUDEPATH += $$PWD/../libs/getLoudness/macx
macx: DEPENDPATH += $$PWD/../libs/getLoudness/macx

macx: LIBS += -L$$PWD/../libs/getLoudness/macx/ -lgetLoudness
macx: PRE_TARGETDEPS += $$PWD/../libs/getLoudness/macx/libgetLoudness.a

win32: INCLUDEPATH += $$PWD/../libs/getLoudness/win32/
win32: DEPENDPATH += $$PWD/../libs/getLoudness/win32/

win32:CONFIG(release, debug|release): LIBS += -L$$PWD/../libs/getLoudness/win32/ -lgetLoudness
else:win32:CONFIG(debug, debug|release): LIBS += -L$$PWD/../libs/getLoudness/win32/ -lgetLoudness_d
